Belgian Amiga Club - ADF Collection/BS1 part 05.zip/BS1 part 5/IM_Install3.adf/piarc.LZH/PALRD.rexx

OS/2 REXX Batch file | 1992-04-09 | 5KB | 186 lines

/*
 * PALRD.rexx
 *
 *  Written by: Pete Patterson
 * Last Update: April 14, 1992
 *         For: Black Belt Systems image processing series IM, IM F/c, and IP.
 * ---------------------------------------------------------------------------
 *    Revision: 1.00
 */

/*
 * open rexxsupport.library -- needed for some functions
 */
if ~show('L',"rexxsupport.library") then do
  if addlib('rexxsupport.library',0,-30,0) then do
      /* everything's ok */
    end;
  else do
    say 'We Have A Library Problem, Unable To Load "rexxsupport.library"';
    say 'Cannot operate rgbxr.rexx without this library - sorry!';
    exit 10;
    end;
  end;

/*
 * This will automatically direct the script to the proper
 * software, if it is running.
 */
prtnme = 'IP_Port'; /* assume Image Professional */
if show('P','IP_Port') = 0 then do
  if show('P','IM_Port') = 0 then do
    say "Can't find image processor's ARexx port!!!"; /* not running? */
    say "This script requires IP, IM or IM F/c to run!";
    exit(20);
    end;
  else do
    prtnme = 'IM_Port'; /* That's the thing about assumptions... */
    end;                 /* We make em, user's break em.          */
  end;

  /*
   * This code attempts to read a file called "picmdpath" from REXX:
   * If it can't find it, the script will assume that the commands
   * associated with this PI Module are in "c:". If the file exists,
   * the script will look in the path that is specified in the file.
   * If you create this file, you MUST put a complete, correct path
   * in it; if the commands are in a sub-directory, you have to put
   * the trailing slash on the path (like, device:dir/).
   *
   */
  cmdpath = 'c:';
  if open(fhandle,'rexx:picmdpath','read') then  /* open the file */
    do
      cmdpath = readln(fhandle);
      call close(fhandle);  /* close the file    */
    end

options;
address;

  prevpath = 'ram:'; /* put user in ram to start with... */

  if show('C',palpath) = 1 then do
    prevpath = getclip(palpath);
    end;

  address(prtnme);
  options results;
  'filerequest "'||prevpath||'","'||bufname||'","","Get IFF Palette"';
  palfile = result;
  options;

  if palfile = 'FR_CANCELLED' then do
    address(prtnme);
    'imtofront';
    exit 0;
    end;

  palfile = expandfilename(palfile);
  thispath = gimmepath(palfile);
  call setclip(palpath,thispath);

  address(prtnme);
  options results;
  'askyn '||'"Verbatim Palette" "Stretch Palette"'
  stretch = result;
  options;

  if stretch then do
    address command cmdpath||'PALRD "'||palfile||'" -s';
    end;
  else do
    address command cmdpath||'PALRD "'||palfile||'"';
    end;
  if rc ~= 0 then do
    address(prtnme);
    'message "Cannot read '||palfile||'"';
    exit 0; /* this is not a proper IFF file */
    end;

  res = open(fhandle,'ram:IP_PALRD.tmp','read');      /* open the file */
  if res then do
    rstring = readln(fhandle);
    parse var rstring colors
    address(prtnme);
    if colors < 256 then do
      options results;
      'askprop '||'"Start offset in palette?" 0 0 '||256-colors
      paloffs = result;
      options;
      end;
    else do
      paloffs = 0;
      end;
    do ccolr = 1 to colors
      rstring = readln(fhandle);
      parse var rstring rv '/' gv '/' bv
       address(prtnme);
      'setpalette '||paloffs+ccolr-1||' '||rv||' '||gv||' '||bv
      end;
    call close(fhandle);
    end;
  address command 'c:delete >nil: ram:IP_PALRD.tmp';

  address(prtnme);
  'imtofront'; /* show user the IM screen */
  /* is there already a primary buffer??? */
  options results;
  'current';
  bufdata = result;
  options;

  exit 0;

/*
 * gimmepath
 *
 * This takes the provided argument and sucks the path out of it, then
 * returns that path to the caller, sans file name.
 */
gimmepath:
  arg fullnamegx;
    tempgx = reverse(fullnamegx);
    lengx = length(fullnamegx);   /* get length of string */
    slashdex = index(tempgx,'/'); /* first occurance of '/' from right */
    colondex = index(tempgx,':');  /* first occurance of ':' from right */
    seploc = 0; /* assumes current dir, no path supplied */
    if slashdex ~= 0 then do /* we assume we are in a DIR */
      seploc = (lengx - slashdex)+1;
      end;
    else do
      if colondex ~= 0 then do /* we assume we are on a device */
        seploc = (lengx - colondex)+1;
        end;
      end;
  gxname = substr(fullnamegx,seploc+1); /* if you ever need it */
  gxpath = left(fullnamegx,seploc);
  return(gxpath);

/*
 * Since this script can't be expected to know where the CD of the user
 * is when this cmd is invoked, we have to check the path the user
 * provides - if it's not specified right from a root, then we have
 * to make it a complete specification from the root.
 */
expandfilename:
  parse arg jfile;
  if index(jfile,':') = 0 then do
    curdir = pragma(D);
    if right(curdir,1) ~= ':' then do
      if right(curdir,1) ~= '/' then do
        if curdir ~= '' then do
          curdir = curdir || '/';
          end;
        end;
      end;
    jfile = curdir||jfile;
    end;
  return(jfile);

rvalue:
  wordnum = c2d(readch(fhandle,1)) * 256;
  wordnum = wordnum + c2d(readch(fhandle,1));
  return wordnum;